tuto9_materials.glsl

Go to the documentation of this file.

 
#version 330
 
#ifdef VERTEX_SHADER
layout(location= 0) in vec3 position;
layout(location= 2) in vec3 normal;
layout(location= 4) in uint material;
 
uniform mat4 mvpMatrix;
uniform mat4 mvMatrix;
 
out vec3 vertex_position;
out vec3 vertex_normal;
flat out uint vertex_material;
/* decoration flat : le varying est un entier, donc pas vraiment interpolable... il faut le declarer explicitement */
 
void main( )
{
    gl_Position= mvpMatrix * vec4(position, 1);
    
    // normale dans le repere camera
    vertex_normal= mat3(mvMatrix) * normal;
    // et transmet aussi l'indice de la matiere au fragment shader...
    vertex_material= material;
}
 
#endif
 
 
#ifdef FRAGMENT_SHADER
out vec4 fragment_color;
 
in vec3 vertex_normal;
flat in uint vertex_material;   // !! decoration flat, le varying est marque explicitement comme non interpolable  !!
 
#define MAX_MATERIALS 16
uniform vec4 materials[MAX_MATERIALS];
 
void main( )
{
    vec3 l= normalize( vec3(0.5, 0.25, 0) );    // todo : passer en parametre...
    vec3 n= normalize(vertex_normal);
    float cos_theta= max(0, dot(n, l));
    
    // recupere la couleur de la matiere du triangle, en fonction de son indice.
    vec4 color= materials[vertex_material];
    
    // terme ambiant
    float ambient= max(0, dot( n, vec3(0, 1, 0) ));
    vec4 ambient_color= color * (1 + ambient) / 2;
    
    fragment_color= 0.2 * ambient_color + color * cos_theta;
}
 
#endif